source: main/trunk/ibisph-view/src/main/webapp/xslt/ibis.xslt @ 19868

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="3.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:xs  ="http://www.w3.org/2001/XMLSchema"
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis xs xsl"
>

        <ibis:doc>
                <name>ibis</name>
                <summary>Library of generic/common ibis specific functions</summary>
                <description>
                        Library of generic/common IBIS specific global variables and functions.
                        These functions are auto included in all pages because this file is 
                        imported by _main.xslt which is a part of all IBISPH-View system HTML 
                        output pages.
                </description>
        </ibis:doc>

        <xsl:import href="_ibis-format.xslt"/>
        <xsl:import href="_ibis-title.xslt"/>
        <xsl:import href="_ibis-path.xslt"/>
        <xsl:import href="_ibis-user.xslt"/>
        <xsl:import href="_ibis-include.xslt"/>


        <!-- ========================= M I S C   P A R A M S / F U N C T I O N S -->
        <xsl:function name="ibis:isNumeric" as="xs:boolean" 
                ibis:doc="Returns 'true' if the value numeric, 'false' otherwise."
        >
                <!-- Bunch of ways to do this:
                        number($value)  = 'NaN'  - doesn't work because can't compare real number to string.
                        string($value) != 'NaN'  - requires value processed via number($value) first.
                        ($value =0) and not(not($value) - requires number conversion first.
                        $value*1 = $value - requires number conversion first.

                        EASIEST:
                        xmlns:xs  ="http://www.w3.org/2001/XMLSchema"
                        $value castable as xs:decimal
                        <xsl:value-of select="$value castable as xs:decimal"/>
                        NOTE: double and float are scientic notation and it doesn't pick
                        up NaN so can't use that test.

                        OTHERS: 
                        <xsl:value-of select="'NaN' != string($convertedValue)"/>
                        <xsl:value-of select="(0 = $convertedValue) or not(not($convertedValue))"/>
                -->
                <xsl:param name="value" ibis:doc="Source value to be tested"/>
                <xsl:variable name="convertedValue" select="number($value)"/>
                <xsl:value-of select="ibis:_isNumeric($convertedValue)"/>
        </xsl:function>

        <xsl:function name="ibis:_isNumeric" as="xs:boolean" 
                ibis:doc="Returns 'true' if the numeric value is numeric, 'false' otherwise."
        >
                <xsl:param name="numericValue" ibis:doc="Source value to be tested"/>
                <xsl:value-of select="($numericValue = 0) or not(not($numericValue))"/>
        </xsl:function>


        <xsl:function name="ibis:isFirstLetter_T_or_Y_or_X" as="xs:boolean" 
                ibis:doc="Returns 'true' if the text is 'T'rue, 'Y'es, or 'x' - 'false' otherwise (case insensitive)."
        >
                        <!-- can also be done by regexp -->
                        <xsl:param name="text" ibis:doc="Source text to be tested"/>
                        <xsl:variable name="firstLetter" select="lower-case(substring(normalize-space($text),1,1))"/>
                        <xsl:value-of select="if(($firstLetter='y') or ($firstLetter='t') or ($firstLetter='x')) then true() else false()"/>
        </xsl:function>


        <xsl:param name="PrinterFriendly" ibis:doc="The 'PrinterFriendly' parameter 
                controls which main root processing template is called.  This enables the 
                system to easily allow for all pages to be made printer friendly.  This 
                parameter is set via the Java controller code and comes from the HTTP
                request URL."
        />
        <xsl:function name="ibis:isPrinterFriendly" as="xs:boolean" 
                ibis:doc="localizes and hides the 'PrinterFriendly' parameter and isTYZ code."
        >
                <xsl:value-of select="ibis:isFirstLetter_T_or_Y_or_X($PrinterFriendly) or ($PrinterFriendly = 'bw') or ($PrinterFriendly = 'BW')"/>
        </xsl:function>


        <xsl:function name="ibis:getJavaScriptValue" as="xs:string"
                ibis:doc="If value exists then returns value otherwise null."
        >
                <xsl:param name="value" ibis:doc="Value to be tested."/>
                <xsl:value-of select="if((string-length($value) != 0) and (string(number($value)) != 'NaN')) then $value else 'null'"/>
        </xsl:function>


        <xsl:function name="ibis:textNodesToJSONArray" 
                ibis:doc="Builds a quoted, comma separated values json string."
        >
                <xsl:param name="textNodes" ibis:doc="nodes to convert."/>
                <xsl:variable name="textNodesCount" select="count($textNodes)"/>
<!-- GARTH TODO:
<xsl:message select="$textNodesCount"/>
-->
                <xsl:text>[</xsl:text>
                <xsl:if test="1 = $textNodesCount">"<xsl:value-of select="$textNodes"/>"</xsl:if>
                <xsl:if test="1 &lt; $textNodesCount">
                        <xsl:for-each select="$textNodes/text()">
                                <xsl:text/><xsl:if test="position() != 1">,</xsl:if>"<xsl:value-of select="."/>"<xsl:text/>
                        </xsl:for-each>
                </xsl:if>
                <xsl:text>]</xsl:text>
        </xsl:function>

</xsl:stylesheet>

<!-- ============================= End of File ============================= -->