source: main/trunk/ibisph-view/src/main/webapp/xslt/html/indicator/profile/Page.xslt @ 19868

Last change on this file since 19868 was 19868, checked in by GarthBraithwaite_STG, 3 years ago

view - more css tweaks. Reworked common.xml to go back to add model maps be referenced. Added complete external path for xslt access.

File size: 5.4 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<xsl:stylesheet version="3.0" 
4        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
5        xmlns:ibis="http://www.ibisph.org"
6
7        exclude-result-prefixes="ibis"
8>
9        <xsl:import href="../../Page.xslt"/>
10
11
12        <ibis:doc>
13                <name>html/indicator/profile/Page</name>
14                <summary>Provides indicator profile specific 'html' API templates</summary>
15                <description>
16                        Provides indicator profile specific 'html' API templates
17                        which are imported by the actual page specific indicator profile XSLTs.
18                </description>
19        </ibis:doc>
20
21        <xsl:param name="Page.contentTitle" 
22                ibis:doc="Provides the page's content title text which is typically
23                        displayed in the content header section.  This variable is a stubb
24                        and should be implemented for each specific type of page.
25                "
26        >
27                Health Indicator Report of <xsl:value-of select="ibis:getIndicatorTitle($indicator)"/>
28        </xsl:param>
29
30        <xsl:param name="Page.metaDescription" select="
31                        if(string-length(/INDICATOR_VIEW/DESCRIPTION) != 0)then
32                                concat(/INDICATOR/DESCRIPTION, ' ; ', /INDICATOR_VIEW/DESCRIPTION)
33                        else
34                                /INDICATOR/DESCRIPTION
35                "
36                ibis:doc="Implementation that returns the INDICATOR and INDICATOR_VIEW/DESCRIPTION."
37        />
38        <xsl:param name="Page.metaKeywords" select="$Page.metaDescription"/>
39
40
41        <xsl:param name="Page.orgUnitName" select="$indicator/ORG_UNIT_NAME"
42                ibis:doc="Provides the associated IP organization unit contact
43                        info text which is typically used in the content footer.  The actual
44                        org unit text is pulled from the 'org_unit.xml' file and is keyed
45                        off of via the '/INDICATOR/ORG_UNIT_NAME' element.
46                "
47        />
48
49
50        <xsl:param name="Page.htmlClass" select="'IndicatorProfile'"/>
51
52
53
54        <!-- DEPENDENCY NOTE: This file is not meant to be imported as a stand alone
55                XSLT library.  This file depends/relies on the $indicator variable and
56                the $ibis.contextPath parameter being defined.
57        -->
58
59        <xsl:template name="Page.specificHeadContent"
60                ibis:doc="Turn off caching if there's an XML URL."
61        >
62                <xsl:if test="string-length($xmlURL) != 0">
63                        <xsl:call-template name="Page.metaNoCacheControl"/>
64                </xsl:if>
65        </xsl:template>
66
67
68        <xsl:template name="Page.options">
69                <xsl:param name="title"/>
70                <xsl:param name="isSummary" select="false()"/>
71
72                <div class="ContentOptions">
73                        <h3><xsl:value-of select="$title"/></h3>
74
75                        <table class="SingleRowTable">
76                                <tr>
77                                        <td><label for="indicatorViews"><h4>Data Views:</h4></label></td>
78                                        <td><label for="moreInformation"><h4>More Information:</h4></label></td>
79                                        <td><label for="relatedIndicators"><h4>Related Indicator Reports:</h4></label></td>
80                                        <td><label for="relatedIndicators"><h4>Associated Health Topics:</h4></label></td>
81                                </tr>
82                                <tr>
83                                        <td>
84                                                <xsl:variable name="currentIndicatorViewName" select="$indicatorView/NAME"/>
85                                                <select name="indicatorViews" id="indicatorViews" onchange="location=this.value; this.value='';">
86                                                        <xsl:for-each select="$indicator/INDICATOR_VIEWS/INDICATOR_VIEW">
87                                                                <option value="{concat($ibis.contextPath, 'indicator/view/', NAME, '.html')}">
88                                                                        <xsl:if test="NAME = $currentIndicatorViewName">
89                                                                                <xsl:attribute name="selected" select="'selected'"/>
90                                                                        </xsl:if>
91                                                                        <xsl:value-of select="TITLE"/>
92                                                                </option>
93                                                        </xsl:for-each>
94                                                        <option value="{concat($ibis.contextPath, 'indicator/summary/', $indicator/NAME, '.html')}">
95                                                                <xsl:if test="true() = $isSummary">
96                                                                        <xsl:attribute name="selected" select="'selected'"/>
97                                                                </xsl:if>
98                                                                Summary Report
99                                                        </option>
100                                                </select>
101                                        </td>
102
103                                        <td>
104                                                <select name="moreInformation" id="moreInformation" onchange="location=this.value; this.value='';">
105                                                        <option value="javascript:location"></option>
106                                                        <option value="{concat($ibis.contextPath, 'indicator/facts/', $indicator/NAME, '.html')}">Important Facts</option>
107                                                <xsl:if test="string-length($indicator/SERVICES_AVAILABLE_TO_PUBLIC) != 0">
108                                                        <option value="{concat($ibis.contextPath, 'indicator/services/', $indicator/NAME, '.html')}">Available Services</option>
109                                                </xsl:if>
110                                                        <option value="{concat($ibis.contextPath, 'indicator/resources/', $indicator/NAME, '.html')}">Resources &amp; Links</option>
111                                                </select>
112                                        </td>
113
114                                        <td>
115                                                <select name="relatedIndicators" id="relatedIndicators" onchange="location=this.value; this.value='';">
116                                                        <option value="javascript:location"></option>
117                                                        <xsl:for-each select="$indicator/RELATIONS/RELATION/RELATED_INDICATORS/RELATED_INDICATOR">
118                                                                <xsl:sort select="SORT_ORDER" order="ascending" data-type="number"/>
119                                                                <option value="{concat($ibis.contextPath, 'indicator/summary/', NAME, '.html')}"><xsl:value-of select="TITLE"/></option>
120                                                        </xsl:for-each>
121                                                </select>
122                                        </td>
123
124                                        <td>
125                                                <select name="associatedHealthTopics" id="associatedHealthTopics" onchange="location=this.value; this.value='';">
126                                                        <option value="javascript:location"></option>
127                                                        <xsl:for-each select="$indicator/TOPICS/TOPIC">
128                                                                <xsl:sort select="SORT_ORDER" order="ascending" data-type="number"/>
129                                                                <option value="{ibis:getCompleteURL(URL)}"><xsl:value-of select="TITLE"/></option>
130                                                        </xsl:for-each>
131                                                </select>
132                                        </td>
133                                </tr>
134                        </table>
135                </div>
136        </xsl:template>
137
138</xsl:stylesheet>
139<!-- ============================= End of File ============================= -->
140
Note: See TracBrowser for help on using the repository browser.