source: main/trunk/ibisph-view/src/main/webapp/xslt/html/indicator/profile/Page.xslt @ 19890

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="3.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis"
>
        <xsl:import href="../../Page.xslt"/>


        <ibis:doc>
                <name>html/indicator/profile/Page</name>
                <summary>Provides indicator profile specific 'html' API templates</summary>
                <description>
                        Provides indicator profile specific 'html' API templates 
                        which are imported by the actual page specific indicator profile XSLTs.
                </description>
        </ibis:doc>

        <xsl:param name="Page.contentTitle" 
                ibis:doc="Provides the page's content title text which is typically 
                        displayed in the content header section.  This variable is a stubb 
                        and should be implemented for each specific type of page.
                "
        >
                Health Indicator Report of <xsl:value-of select="ibis:getIndicatorTitle($indicator)"/>
        </xsl:param>

        <xsl:param name="Page.metaDescription" select="
                        if(string-length(/INDICATOR_VIEW/DESCRIPTION) != 0)then
                                concat(/INDICATOR/DESCRIPTION, ' ; ', /INDICATOR_VIEW/DESCRIPTION)
                        else
                                /INDICATOR/DESCRIPTION
                "
                ibis:doc="Implementation that returns the INDICATOR and INDICATOR_VIEW/DESCRIPTION."
        />
        <xsl:param name="Page.metaKeywords" select="$Page.metaDescription"/>


        <xsl:param name="Page.orgUnitName" select="$indicator/ORG_UNIT_NAME"
                ibis:doc="Provides the associated IP organization unit contact 
                        info text which is typically used in the content footer.  The actual 
                        org unit text is pulled from the 'org_unit.xml' file and is keyed 
                        off of via the '/INDICATOR/ORG_UNIT_NAME' element.
                "
        />


        <xsl:param name="Page.htmlClass" select="'IndicatorProfile'"/>



        <!-- DEPENDENCY NOTE: This file is not meant to be imported as a stand alone 
                XSLT library.  This file depends/relies on the $indicator variable and 
                the ibis.baseRequestPath parameter being defined.
        -->

        <xsl:template name="Page.specificHeadContent"
                ibis:doc="Turn off caching if there's an XML URL."
        >
                <xsl:if test="string-length($xmlURL) != 0">
                        <xsl:call-template name="Page.metaNoCacheControl"/>
                </xsl:if>
        </xsl:template>


        <xsl:template name="Page.options">
                <xsl:param name="title"/>
                <xsl:param name="pageType"/>

                <div class="ContentOptions">
                        <h3><xsl:value-of select="$title"/></h3>

                        <div class="Container">
                                <div>
                                        <label for="indicatorViews"><h4>Data Views:</h4></label>
                                        <xsl:variable name="currentIndicatorViewName" select="$indicatorView/NAME"/>
                                        <select name="indicatorViews" id="indicatorViews" onchange="location=this.value; this.value='';">
                                        <xsl:if test="('summary' != $pageType) and ('view' != $pageType)">
                                                <option value="javascript:location" selected="selected"></option>
                                        </xsl:if>
                                        <xsl:for-each select="$indicator/INDICATOR_VIEWS/INDICATOR_VIEW">
                                                <option value="{concat($ibis.baseRequestPath, 'indicator/view/', NAME, '.html')}">
                                                        <xsl:if test="('view' = $pageType) and (NAME = $currentIndicatorViewName)">
                                                                <xsl:attribute name="selected" select="'selected'"/>
                                                        </xsl:if>
                                                        <xsl:value-of select="TITLE"/>
                                                </option>
                                        </xsl:for-each>
                                                <option value="{concat($ibis.baseRequestPath, 'indicator/summary/', $indicator/NAME, '.html')}">
                                                        <xsl:if test="'summary' = $pageType">
                                                                <xsl:attribute name="selected" select="'selected'"/>
                                                        </xsl:if>
                                                        Summary Report
                                                </option>
                                        </select>
                                </div>

                                <div>
                                        <label for="moreInformation"><h4>More Information:</h4></label>
                                        <select name="moreInformation" id="moreInformation" onchange="location=this.value; this.value='';">
                                                <xsl:if test="('services' != $pageType) and ('facts' != $pageType) and ('resources' != $pageType)">
                                                <option value="javascript:location" selected="selected"></option>
                                                </xsl:if>
                                                <option value="{concat($ibis.baseRequestPath, 'indicator/facts/', $indicator/NAME, '.html')}">
                                                        <xsl:if test="'facts' = $pageType">
                                                                <xsl:attribute name="selected" select="'selected'"/>
                                                        </xsl:if>
                                                        Important Facts
                                                </option>
                                        <xsl:if test="string-length($indicator/SERVICES_AVAILABLE_TO_PUBLIC) != 0">
                                                <option value="{concat($ibis.baseRequestPath, 'indicator/services/', $indicator/NAME, '.html')}">
                                                        <xsl:if test="'services' = $pageType">
                                                                <xsl:attribute name="selected" select="'selected'"/>
                                                        </xsl:if>
                                                        Available Services
                                                </option>
                                        </xsl:if>
                                                <option value="{concat($ibis.baseRequestPath, 'indicator/resources/', $indicator/NAME, '.html')}">
                                                        <xsl:if test="'resources' = $pageType">
                                                                <xsl:attribute name="selected" select="'selected'"/>
                                                        </xsl:if>
                                                        Resources &amp; Links
                                                </option>
                                        </select>
                                </div>

                                <xsl:if test="0 != count($indicator/RELATIONS/RELATION/RELATED_INDICATORS/RELATED_INDICATOR)">
                                <div>
                                        <label for="relatedIndicators"><h4>Related Indicator Reports:</h4></label>
                                        <select name="relatedIndicators" id="relatedIndicators" onchange="location=this.value; this.value='';">
                                                <option value="javascript:location"></option>
                                                <xsl:for-each select="$indicator/RELATIONS/RELATION/RELATED_INDICATORS/RELATED_INDICATOR">
                                                        <xsl:sort select="SORT_ORDER" order="ascending" data-type="number"/>
                                                        <option value="{concat($ibis.baseRequestPath, 'indicator/summary/', NAME, '.html')}"><xsl:value-of select="TITLE"/></option>
                                                </xsl:for-each>
                                        </select>
                                </div>
                                </xsl:if>

                                <xsl:if test="0 != count($indicator/TOPICS/TOPIC)">
                                <div>
                                        <label for="relatedIndicators"><h4>Associated Health Topics:</h4></label>
                                        <select name="associatedHealthTopics" id="associatedHealthTopics" onchange="location=this.value; this.value='';">
                                                <option value="javascript:location"></option>
                                                <xsl:for-each select="$indicator/TOPICS/TOPIC">
                                                        <xsl:sort select="SORT_ORDER" order="ascending" data-type="number"/>
                                                        <option value="{ibis:getCompleteURL(URL)}"><xsl:value-of select="TITLE"/></option>
                                                </xsl:for-each>
                                        </select>
                                </div>
                                </xsl:if>
                        </div>
                </div>
        </xsl:template>

</xsl:stylesheet>
<!-- ============================= End of File ============================= -->