source: main/trunk/ibisph-view/src/main/webapp/xslt/html/HTMLContentPage.xslt @ 19868

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="3.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis"
>
        <xsl:import href="Page.xslt"/>
        <xsl:import href="SiteSpecific.xslt"/>


        <ibis:doc>
                <name>html/HTMLContentPage</name>
                <summary>Core templates that handle the 'HTML_CONTENT' XML elements to 
                        produce an IBIS-PH HTML page.
                </summary>
                <description>
                        Base XSLT that provides the templates to transform 'HTML_CONTENT' type
                        XML content to IBISPH-View HTML pages.  This template and the 'HTML_CONTENT' 
                        XML data files form a simple mechanism to help keep all static type pages 
                        more easily maintained and consistent.  This framework provides the 
                        advantages of server side includes (SSI) while providing some extra 
                        value like being able to reference resources using a relative path.
                        <br/><br/>

                        URL NOTE: This template contains a special way to handle IBIS type URLs.
                        Instead of hard coding the link to include the application context and 
                        path, a relative type path can be used with an "ibis:" namespace.  This 
                        causes the web app context prefix to be added to the resource path so 
                        that the path is free of context deployment paths.  If the link is within
                        the same 'folder' (as defined in with the resource mapping), then the 
                        'ibis:' is not needed.  However, if it is NOT, then it should be used.
                        An example is the 'about/content_usage.html' page referencing a graphic
                        image 'image/OH.gif'.  If the link is coded using relative addressing
                        and the system is deployed to the webapp context of 'ibisph-view' then
                        this link will not work because the server will look for the image with
                        a path of: 'ibisph-view/about/image/DOH.gif'.  To work, the link would 
                        have to be coded as '/ibisph-view/image/DOH.gif' but what happens if this
                        save system is deployed as the root application.  Then the link would 
                        have to be coded as '/image/DOH.gif' etc.  The processing of the link
                        by this template automatically adds the appropriate webapp content prefix
                        so that the resources can be relatively addressed.  Of couse if a relative
                        address is really wanted then simply skip placing the 'ibis:' namespace
                        prefix to the link's attribute.
                </description>
        </ibis:doc>


        <!-- ~~~~~~~~~~~~~~~~~~~~~~~ PARAMS / VARIABLES ~~~~~~~~~~~~~~~~~~~~~~~~ -->
        <xsl:param name="Page.pageTitle" select="HTML_CONTENT/TITLE"
                ibis:doc="HTML API template implementation that provides the HTML page's title text."
        />
        <xsl:param name="Page.metaDescription" select="HTML_CONTENT/DESCRIPTION"
                ibis:doc="HTML API template implementation that provides the HTML page's 'description' meta tag text.  Defaults to the 'HTML_CONTENT/DESCRIPTION' element."
        />
        <xsl:param name="Page.metaKeywords" select="HTML_CONTENT/KEYWORDS"
                ibis:doc="HTML API template implementation that provides the HTML page's 'keyword' meta tag text.  Defaults to the 'HTML_CONTENT/KEYWORDS' element."
        />
        <xsl:param name="Page.htmlClass" select="HTML_CONTENT/HTML_CLASS"
                ibis:doc="ability to specify the main html css class."
        />


        <!-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ TEMPLATES ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ -->
        <xsl:template name="Page.specificHeadContent" 
                ibis:doc="HTML API template implementation that provides the ability to specify other HTML HEAD tag content.  Defaults to the 'HTML_CONTENT/OTHER_HEAD_CONTENT' element.">
                <xsl:apply-templates select="HTML_CONTENT/OTHER_HEAD_CONTENT/* | HTML_CONTENT/OTHER_HEAD_CONTENT/text() | HTML_CONTENT/OTHER_HEAD_CONTENT/@*" mode="ibis.copy"/>
        </xsl:template>



        <xsl:template name="Page.contentBody" ibis:doc="HTML API template implementation 
                that provides main HTML body content for the page.  Defaults to copying
                all elements and attributes of the the 'HTML_CONTENT/CONTENT' element."
        >
                <!-- used an apply templates so that the ibis: stuff would be handled -->
                <xsl:apply-templates select="HTML_CONTENT/CONTENT/(text() | *)" mode="ibis.copy"/>
        </xsl:template>


        <xsl:template match="ibis:include"
                ibis:doc="Provides include processing."
        >
                <xsl:apply-templates select=
                        "if(exists(@children-only-flag)) 
                                then document(@href, /)/(text() | *)
                                else document(@href, /)
                        "
                        mode="ibis.copy"
                />
        </xsl:template>



        <xsl:template match="ibis:ContentBlock" mode="ibis.copy"
                ibis:doc="Provides ability to more easily embed a fixed content block   
                        into the page's content.
                "
        >
                <xsl:call-template name="ContentContainer.contentBlock">
                        <xsl:with-param name="containerID" select="if(0 != string-length(@id)) then @id else NAME"/>
                        <xsl:with-param name="contentContainerClass" select="@contentContainerClass"/>
                        <xsl:with-param name="additionalClasses"     select="@additionalClasses"/>
                        <xsl:with-param name="title"       select="TITLE"/>
                        <xsl:with-param name="titleLevel"  select="if(exists(@titleLevel)) then @titleLevel else 3"/>   
                        <xsl:with-param name="description" select="DESCRIPTION"/>
                        <xsl:with-param name="content"     select="CONTENT"/>
                        <xsl:with-param name="contentBlockType" select="if(0 != string-length(@contentBlockType)) then @contentBlockType else $ContentContainer.defaultContentBlockType"/>
                        <xsl:with-param name="expandableControlType" select="if(0 != string-length(@expandableControlType)) then @expandableControlType else $ContentContainer.expandableControlType"/>
                        <xsl:with-param name="expandableContentShow" select="if(0 != string-length(@expandableContentShow)) then @expandableContentShow else SHOW"/>
                        <xsl:with-param name="expandableControlName" select="if(0 != string-length(@expandableControlName)) then @expandableControlName else $ContentContainer.expandableControlName"/>
                        <xsl:with-param name="expandableControlAccesskey" select="@expandableControlAccesskey"/>
                        <xsl:with-param name="addWikiAttribute" select="if(0 != string-length(@addWikiAttribute)) then @addWikiAttribute else $ContentContainer.addWikiAttributeToContentContainer"/>
                </xsl:call-template>
        </xsl:template>



        <xsl:template match="ibis:ExpandableContent" mode="ibis.copy"
                ibis:doc="Provides ability to more easily embed an expandable content block 
                        into the page's content.  Note that the approp CSS will need to be included.
                        The control and container require an 'id' attribute.  This ID uses the
                        optional NAME sub element.  If NAME doesn't exist then postion() is used.  
                        This will create unique ID's in most cases.  The CONTENT text() and 
                        sub elements will be ibis:copied into the assoc content container DIV.

                        Dropdown content are is just as easily coded directly in the CONTENT 
                        so no template call/special processing is implemented as it just gets 
                        in the way.
                "
        >
                <xsl:call-template name="ContentContainer.expandable">
                        <xsl:with-param name="controlID"   select="@id"/>
                        <xsl:with-param name="controlType" select="@controlType"/>
                        <xsl:with-param name="additionalClasses" select="@additionalClasses"/>
                        <xsl:with-param name="controlName" select="
                                if(not(@controlName)) then NAME
                                else @controlName
                        "/>
                        <xsl:with-param name="title"       select="TITLE"/>
                        <xsl:with-param name="titleLevel"  select="if(exists(@titleLevel)) then @titleLevel else 2"/>   
                        <xsl:with-param name="description" select="DESCRIPTION"/>
                        <xsl:with-param name="content"     select="CONTENT"/>
                        <xsl:with-param name="show"        select="exists(SHOW) or (string-length(@show) != 0)"/>
                </xsl:call-template>
        </xsl:template>



        <xsl:template match="ibis:SelectionsList" mode="ibis.copy"
                ibis:doc="Provides ability to more easily create a list structure based 
                        on the standard SELECTIONS/SELECTION structure.  The controlType and
                        class controls indentured/expandable behavior.  Note that the approp 
                        CSS will need to be included.  This code handles sub ibis:includes
                        so that a MENU structure can be included.  If the container element 
                        does NOT have a direct child element named SELECTIONS then the optional
                        SELECTIONS_CONTAINER_ELEMENT_NAME can be used.  If the INCLUDE_SUB_LISTS
                        element is present then the list will be processed for sub lists.
                "
        >
                <!-- variable is needed to process any ibis:include statements -->
                <xsl:param name="ibisIncludeProcessedContent">
                        <xsl:apply-templates select="*" mode="ibis.copy"/>
                </xsl:param>
                <xsl:param name="selections"
                        select="
                                if(exists(SELECTIONS_CONTAINER_ELEMENT_NAME)) 
                                        then $ibisIncludeProcessedContent//*[name()=$ibisIncludeProcessedContent/SELECTIONS_CONTAINER_ELEMENT_NAME]/*
                                        else $ibisIncludeProcessedContent
                        "
                />
                <xsl:call-template name="SelectionsList.processSelections">
                        <xsl:with-param name="containerID"    select="@id"/>
                        <xsl:with-param name="containerClass" select="@class"/>
                        <xsl:with-param name="controlType"    select="@controlType"/>
                        <xsl:with-param name="selections"     select="$selections"/>
                </xsl:call-template>
        </xsl:template>



        <xsl:template match="ibis:ContiditionalSection" mode="ibis.copy"
                ibis:doc="Provides ability include/exclude certain sections of HTML 
                        CONTENT.  For this to work, an overriden callback type template
                        is used.  This template is passed the section's ID.  The template
                        must then determine if the section should be included.  The template
                        determines this by XML, the passed in ID, and any other parameters
                        that have been passed into the transformer process.  

                        For working examples see repository for the user related XSLT and 
                        HTML_CONTENT ~May 2013.
                "
        >
                <xsl:param name="test">
                        <xsl:call-template name="HTMLContent.includeConditionalSection">
                                <xsl:with-param name="sectionID" select="@id"/>
                        </xsl:call-template>
                </xsl:param>

                <xsl:if test="ibis:isFirstLetter_T_or_Y_or_X($test)">
                        <xsl:apply-templates select="(text() | *)" mode="ibis.copy"/>
                </xsl:if>
        </xsl:template>



        <xsl:template name="HTMLContent.includeConditionalSection"
                ibis:doc="Callback type template that controls if the section should be
                        processed.  If the template returns 'T', 'X', or 'Y' then that 
                        content will be included.  If nothing or 'F', 'N' then that cotent
                        will be omitted.  Default is to omit everything.  Sub XSLTs must
                        override this template and determine if the content should be shown
                        based on the XML, params passed in, and the section's ID attribute.
                "
        >
                <xsl:param name="sectionID"/>
        </xsl:template>



        <xsl:template match="ibis:help" mode="ibis.copy"
                ibis:doc="Provides a help button/popup."
        >
                <xsl:call-template name="Help.content">
                        <xsl:with-param name="help" select="."/>
                </xsl:call-template>
        </xsl:template>

</xsl:stylesheet>
<!-- ============================= End of File ============================= -->