source: main/branches/2.1/src/main/webapps/ibisph-view/xslt/html/user/queryselections/Page.xslt @ 3663

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="2.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis"
>
        <xsl:import href="../../Page.xslt"/>
        <xsl:import href="../../query/definition/list/QueryDefinitions.xslt"/>


        <ibis:doc>
                <name>html/user/queryselections/Page</name>
                <summary>core "Page" templates needed to produce the user's query selections.</summary>
                <description>
                </description>

                <author>Garth Braithwaite</author>
                <company>Software Technology Group/CDC/Utah Department of Health</company>
        </ibis:doc>


        <xsl:param name="Page.pageTitle" ibis:doc="Page's title text.">My Queries List</xsl:param>


        <xsl:param name="QueryDefinitions"/>
        <xsl:param name="ProtectedSelections" select="/"/>
        <xsl:param name="UserAuthorities"/>



        <!-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ TEMPLATES ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ -->
        <xsl:template name="Page.specificScript"
                ibis:doc="HTML API template implementation/override that provides the
                        'selection' Javascript file links for the module selection page."
        >
                <!-- enhanced_element and event_manager are already loaded via \site_specific_page.xslt's standard script. -->
                <script type="text/javascript" src="{$ibis.urlPrefix}js/ShowHideBlockControl.js"/>

                <script type="text/javascript">
                        // <![CDATA[
                        var sectionControl = new ShowHideBlockControl("control", "ExpandableSectionControlOpen", "container", "ExpandableSectionContainerShow");
                        var treeControl    = new ShowHideBlockControl("control", "Open", "container");
                        // ]]>
                </script>
        </xsl:template>



        <xsl:template name="Page.sectionsContent"
                ibis:doc="Main page content template that displays the user's query 
                        definitions and any secure/protected query module selections.
                "
        >
                <xsl:param name="authorizedSelections" select="$ProtectedSelections/SELECTIONS/SECTIONS/SECTION/SELECTIONS/SELECTION[AUTHORITIES/AUTHORITY = $UserAuthorities/AUTHORITIES/AUTHORITY]"/>

                Welcome to Your Queries.  This page shows the query modules that you 
                have defined and saved or have access to.  To reach this page you must 
                be logged in.  If you have not logged in or are not seeing the selections 
                you think you should either logout and log back in as the appropriate 
                user or login for the first time.  If you think that there is a problem
                please contact the system administrator of this application (see the 
                contact link in the footer of this page).
                <br/><br/>

                <xsl:variable name="authorizedSelectionsCount" select="count($ProtectedSelections/SELECTIONS/SECTIONS/SECTION/SELECTIONS/SELECTION[AUTHORITIES/AUTHORITY = $UserAuthorities/AUTHORITIES/AUTHORITY])"/>
                <xsl:if test="0 = $authorizedSelectionsCount">
                        <xsl:call-template name="QueryDefinitions.runEditSelectionList">
                                <xsl:with-param name="queryDefinitions" select="$QueryDefinitions/QUERY_DEFINITIONS"/>
                        </xsl:call-template>
                </xsl:if>

                <style>
                        a.ExpandableSectionControl
                        {
                                background-color: #003366 !important;
                        }
                </style>
                <xsl:if test="0 != $authorizedSelectionsCount">
                        <a name="controlUserQueryDefinitions" id="controlUserQueryDefinitions" 
                                href="javascript:sectionControl.toggle('UserQueryDefinitions');" 
                                class="ExpandableSectionControl ExpandableSectionControlOpen" 
                                title="User Query Definition Selections"
                        >
                                <span class="Icon"/>
                                Your Saved Query Definitions
                        </a>
                        <div id="containerUserQueryDefinitions" class="ExpandableSectionContainer ExpandableSectionContainerShow">
                                <xsl:call-template name="QueryDefinitions.runEditSelectionList">
                                        <xsl:with-param name="queryDefinitions" select="$QueryDefinitions/QUERY_DEFINITIONS"/>
                                </xsl:call-template>
                        </div><br/>

                        <a name="controlProtectedQueries" id="controlProtectedQueries" 
                                href="javascript:sectionControl.toggle('ProtectedQueries');" 
                                class="ExpandableSectionControl ExpandableSectionControlOpen" 
                                title="Protected Query Selections"
                        >
                                <span class="Icon"/>
                                Your Protected Query Selections
                        </a>

                        <div id="containerProtectedQueries" class="ExpandableSectionContainer ExpandableSectionContainerShow">
                                <xsl:call-template name="Page.protectedSelections">
                                        <xsl:with-param name="authorizedSelections" 
                                                select="$ProtectedSelections/SELECTIONS/SECTIONS/SECTION/SELECTIONS/SELECTION[AUTHORITIES/AUTHORITY = $UserAuthorities/AUTHORITIES/AUTHORITY]"
                                        />
                                </xsl:call-template>
                        </div>
                </xsl:if>

        </xsl:template>



        <xsl:template name="Page.protectedSelections">
                <xsl:param name="authorizedSelections"/>

                <table cellspacing="0" cellpadding="0" border="1" class="Info ExtraCellPadding"
                        summary="table of all your query definition selections."
                        caption="alphabetical listing for all your query definition selections."
                >
                        <tr>
                                <th scope="col" width="600" title="secure query module selections">Protected Query Selections</th>
                        </tr>

                <!-- loop for all definitions -->
                <xsl:for-each select="$authorizedSelections">
                <xsl:sort select="TITLE"/>
                        <tr>
                                <td title="protected query selection">
                                        <a href="{$ibis.urlPrefix}{LOCAL_URL}" title="click this link to go to the query selection page.">
                                                <xsl:value-of select="TITLE"/>
                                        </a>
                                </td>
                        </tr>
                </xsl:for-each>

                </table>
                <div class="RecordCount">Total Secure Query Selections Count: <xsl:value-of select="count($authorizedSelections)"/></div>
        </xsl:template>

</xsl:stylesheet>
<!-- ============================= End of File ============================= -->