source: main/branches/2.1/src/main/webapps/ibisph-view/xslt/html/query/module/result/SiteSpecific.xslt @ 3663

Last change on this file since 3663 was 3663, checked in by Garth Braithwaite, 10 years ago

java and view webapp - commit that has most of model map. committing before ripping out some code and cleaning up more model maps.

File size: 5.8 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<xsl:stylesheet version="2.0" 
4        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
5        xmlns:ibis="http://www.ibisph.org"
6
7        exclude-result-prefixes="ibis"
8>
9        <xsl:import href="../SiteSpecific.xslt"/>
10
11
12        <ibis:doc>
13                <name>html/query/result/SiteSpecific</name>
14                <summary>Provides adopter 'query/result' site specific template overrides</summary>
15                <description>
16                        Provides an overridden 'siteSpecific.topMenu'
17                        API template call so that the banner can be turned off.  This
18                        template also includes the 'css/query.css' links and other adopter specific
19                        code.
20                </description>
21
22                <author>Garth Braithwaite</author>
23                <company>Software Technology Group/CDC/Utah Department of Health</company>
24        </ibis:doc>
25
26
27        <!-- ~~~~~~~~~~~~~~~~~~~~~~~ PARAMS / VARIABLES ~~~~~~~~~~~~~~~~~~~~~~~~ -->
28        <xsl:param name="SiteSpecific.builderURL" select="concat($ibis.urlPrefix, 'query/builder', /QUERY_MODULE/REQUEST/CONFIGURATION_PATH, '.html')"
29                ibis:doc="Builder page URL."
30        />
31
32
33        <!-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ TEMPLATES ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ -->
34        <xsl:template  name="SiteSpecific.contextNavigation"
35                ibis:doc="Query Result left nav menu - specific to the current module config."
36        >
37                <xsl:param name="selections">
38                        <SELECTIONS>
39                                <SELECTION>
40                                        <URL><xsl:value-of select="$SiteSpecific.builderURL"/></URL>
41                                        <DESCRIPTION>Not seeing what you want? Click this to go to the query builder page.</DESCRIPTION>
42                                        <TITLE>Query Definition</TITLE>
43                                </SELECTION>
44                                <SELECTION>
45                                        <URL><xsl:value-of select="concat($ibis.urlPrefix, 'query/result', /QUERY_MODULE/REQUEST/CONFIGURATION_PATH, '.html?Reload=x')"/></URL>
46                                        <DESCRIPTION>Runs the query using default criteria.</DESCRIPTION>
47                                        <TITLE>Default Query Result</TITLE>
48                                </SELECTION>
49                                <SELECTION>
50                                        <URL><xsl:value-of select="concat($ibis.urlPrefix, /QUERY_MODULE/QUERY_CONFIGURATION_SELECTION/LOCAL_URL)"/></URL>
51                                        <DESCRIPTION>Click this button to choose different dataset.</DESCRIPTION>
52                                        <TITLE>Query Dataset Configuration Selection</TITLE>
53                                        <ADDITIONAL_CLASSES>MenuItem2Lines</ADDITIONAL_CLASSES>
54                                </SELECTION>
55
56                                <xsl:if test="not($Result.configuration/CRITERIA/EXCLUDE/GRAPHIC_NAMES/ALL_FLAG)">
57                                        <SELECTION>
58                                                <DESCRIPTION>Available Graphics/Charts</DESCRIPTION>
59                                                <TITLE>Graphical Charts</TITLE>
60                                                <SELECTIONS>
61                                                        <xsl:for-each select="$Result.charts/CHART[
62                                                                (NAME != $Result.queryModule/REQUEST/GRAPHIC_NAME) and
63                                                                not(NAME = $Result.configuration/CRITERIA/EXCLUDE/GRAPHIC_NAMES/GRAPHIC_NAME)]"
64                                                        >
65                                                                <xsl:sort select="SORT_ODRER" order="ascending" data-type="number"/>
66
67                                                                <SELECTION>
68                                                                        <URL>?GraphicName=<xsl:value-of select="NAME"/></URL>
69                                                                        <DESCRIPTION>Display the data in a <xsl:value-of select="TITLE"/> graph</DESCRIPTION>
70                                                                        <TITLE><xsl:value-of select="TITLE"/></TITLE>
71                                                                </SELECTION>
72                                                        </xsl:for-each>
73
74                                                        <xsl:if test="exists($Result.configuration/MAP[
75                                                          (CHLOROPLETH_VALUES_MEASURE_NAME=/QUERY_MODULE/REQUEST/MEASURE_NAME)
76                                                           or (DATA_VALUES_MEASURE_NAME   =/QUERY_MODULE/REQUEST/MEASURE_NAME)])">
77                                                                <SELECTION>
78                                                                        <URL>?GraphicName=Map</URL>
79                                                                        <DESCRIPTION>Display the data in a map</DESCRIPTION>
80                                                                        <TITLE>Map</TITLE>
81                                                                </SELECTION>
82                                                        </xsl:if>
83                                                </SELECTIONS>
84                                        </SELECTION>
85                                </xsl:if>
86
87                                <xsl:if test="(count($Result.displayableMeasures) &gt; 1)">
88                                        <SELECTION>
89                                                <DESCRIPTION>Select different data measure</DESCRIPTION>
90                                                <TITLE>Other Measures</TITLE>
91                                                <SELECTIONS>
92                                                        <xsl:for-each select="$Result.displayableMeasures">
93
94                                                                <xsl:if test="current()/NAME != /QUERY_MODULE/REQUEST/MEASURE_NAME">
95                                                                        <SELECTION>
96                                                                                <URL>?MeasureName=<xsl:value-of select="NAME"/></URL>
97                                                                                <DESCRIPTION>Display the <xsl:value-of select="TITLE"/> data measure</DESCRIPTION>
98                                                                                <TITLE><xsl:value-of select="TITLE"/></TITLE>
99                                                                        </SELECTION>
100                                                                </xsl:if>
101                                                        </xsl:for-each>
102                                                </SELECTIONS>
103                                        </SELECTION>
104                                </xsl:if>
105
106                                <SELECTION>
107                                        <URL><xsl:value-of select="concat(replace($Result.resultURL, '.html', '.xls'), '?PrinterFriendly=true')"/></URL>
108                                        <DESCRIPTION>Click this button to have this page automatically put into Microsoft Excel.</DESCRIPTION>
109                                        <TITLE>Output to Excel</TITLE>
110                                </SELECTION>
111                                <SELECTION>
112                                        <URL><xsl:value-of select="concat($ibis.urlPrefix, 'query/configuration', /QUERY_MODULE/REQUEST/CONFIGURATION_PATH, '.xml')"/></URL>
113                                        <DESCRIPTION>Click this button to get the raw module data as XML.</DESCRIPTION>
114                                        <TITLE>XML View</TITLE>
115                                </SELECTION>
116
117                                <SELECTION>
118                                        <URL><xsl:value-of select="concat($ibis.urlPrefix, 'save/query/result')"/></URL>
119                                        <DESCRIPTION>Click this button to edit the query.</DESCRIPTION>
120                                        <TITLE>Save Query Definition</TITLE>
121                                </SELECTION>
122                        </SELECTIONS>
123                </xsl:param>
124
125                <xsl:apply-templates select="$selections/SELECTIONS" mode="Menu"/>
126        </xsl:template>
127
128
129        <xsl:template name="SiteSpecific.navigationPath"
130                ibis:doc="Hook that allows for bread crumb trails..."
131        >
132                <a href="{$ibis.urlPrefix}" title="IBIS-PH Website">IBIS-PH</a> &gt;
133                <a href="{$ibis.urlPrefix}query" title="IBIS-PH Website Dataset Queries">Dataset Queries</a> &gt; 
134                <a title="Query module configuration selection page">
135                        <xsl:attribute name="href" select="concat($ibis.urlPrefix, /QUERY_MODULE/QUERY_CONFIGURATION_SELECTION/LOCAL_URL)"/>
136                        <xsl:value-of select="/QUERY_MODULE/QUERY_CONFIGURATION_SELECTION/TITLE"/></a> &gt; 
137                <a href="{$SiteSpecific.builderURL}" title="Query module builder page">Query Builder</a>
138        </xsl:template>
139
140</xsl:stylesheet>
141<!-- ============================= End of File ============================= -->
142
Note: See TracBrowser for help on using the repository browser.