source: main/branches/2.1/src/main/webapps/ibisph-view/xslt/html/HTMLContentPage.xslt @ 3663

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="2.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis"
>
        <xsl:import href="Page.xslt"/>
        <xsl:import href="SelectionTree.xslt"/>
        <xsl:import href="SelectionList.xslt"/>


        <ibis:doc>
                <name>html/HTMLContentPage</name>
                <summary>Core templates that handle the 'HTML_CONTENT' XML elements to 
                        produce an IBIS-PH HTML page.
                </summary>
                <description>
                        Base XSLT that provides the templates to transform 'HTML_CONTENT' type
                        XML content to IBISPH-View HTML pages.  This template and the 'HTML_CONTENT' 
                        XML data files form a simple mechanism to help keep all static type pages 
                        more easily maintained and consistant.  This framework provides the 
                        advantages of server side indlucdes (SSI) while providing some extra 
                        value like being able to reference resources using a relative path.
                        <br/><br/>

                        URL NOTE: This template contains a special way to handle IBIS type URLs.
                        Instead of hard coding the link to include the application context and 
                        path, a relative type path can be used with an "ibis:" namespace.  This 
                        causes the web app context prefix to be added to the resource path so 
                        that the path is free of context deployment paths.  If the link is within
                        the same 'folder' (as defined in with the resource mapping), then the 
                        'ibis:' is not needed.  However, if it is NOT, then it should be used.
                        An example is the 'home/content_usage.html' page referencing a graphic
                        image 'image/OH.gif'.  If the link is coded using relative addressing
                        and the system is deployed to the webapp context of 'ibisph-view' then
                        this link will not work because the server will look for the image with
                        a path of: 'ibisph-view/home/image/DOH.gif'.  To work, the link would 
                        have to be coded as '/ibisph-view/image/DOH.gif' but what happens if this
                        save system is deployed as the root application.  Then the link would 
                        have to be coded as '/image/DOH.gif' etc.  The processing of the link
                        by this template automatically adds the appropriate webapp content prefix
                        so that the resources can be relatively addressed.  Of couse if a relative
                        address is really wanted then simply skip placing the 'ibis:' namespace
                        prefix to the link's attribute.
                </description>

                <author>Garth Braithwaite</author>
                <company>Software Technology Group/CDC/Utah Department of Health</company>
        </ibis:doc>



        <!-- ~~~~~~~~~~~~~~~~~~~~~~~ PARAMS / VARIABLES ~~~~~~~~~~~~~~~~~~~~~~~~ -->
        <xsl:param name="UserAuthorities"
                ibis:doc="User's Role(s)/Authorities that controls if the selection should
                        be included in the output e.g. controls if the user can see the 
                        selection.  Injected by the transformation process as a parameter map.
                "
        />

        <xsl:param name="Page.pageTitle" select="HTML_CONTENT/TITLE"
                ibis:doc="HTML API template implementation that provides the HTML page's title text."
        />

        <xsl:param name="Page.sectionsTitle" select="$Page.pageTitle"
                ibis:doc="Returns the value of the 'HTML_CONTENT/TITLE' element."
        />



        <!-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ TEMPLATES ~~~~~~~~~~~~~~~~~~~~~~~~~~~~ -->
        <xsl:template name="Page.metaDescription" ibis:doc="HTML API template implementation that provides the HTML page's 'description' meta tag text.  Defaults to the 'HTML_CONTENT/DESCRIPTION' element.">
                <xsl:value-of select="HTML_CONTENT/DESCRIPTION"/>
        </xsl:template>

        <xsl:template name="Page.metaKeywords" ibis:doc="HTML API template implementation that provides the HTML page's 'keyword' meta tag text.  Defaults to the 'HTML_CONTENT/KEYWORDS' element.">
                <xsl:value-of select="HTML_CONTENT/KEYWORDS"/>
        </xsl:template>

        <xsl:template name="Page.otherHeadContent" ibis:doc="HTML API template implementation that provides the ability to specify other HTML HEAD tag content.  Defaults to the 'HTML_CONTENT/OTHER_HEAD_CONTENT' element.">
                <xsl:apply-templates select="HTML_CONTENT/OTHER_HEAD_CONTENT/* | HTML_CONTENT/OTHER_HEAD_CONTENT/text() | HTML_CONTENT/OTHER_HEAD_CONTENT/@*" mode="ibis.copy"/>
        </xsl:template>

        <xsl:template name="Page.specificCSS" ibis:doc="HTML API template 
                implementation that provides the ability to specify other HTML HEAD CSS 
                links and style definitions. Defaults to the 'HTML_CONTENT/OTHER_CSS' element.
                Note that this element is NOT wrapped between 'style' tags - the contents 
                are simply dumped into the HTML/HEAD element as is - by default."
        >
                <xsl:apply-templates select="HTML_CONTENT/OTHER_CSS/* | HTML_CONTENT/OTHER_CSS/text() | HTML_CONTENT/OTHER_CSS/@*" mode="ibis.copy"/>
        </xsl:template>

        <xsl:template name="Page.specificScript" ibis:doc="HTML API template 
                implementation that provides the ability to specify other HTML HEAD 
                Javascript links and inline code.  Defaults to the 'HTML_CONTENT/OTHER_SCRIPT' 
                element.  Note that this element is NOT wrapped between 'javascript' tags 
                - the contents are simply dumped into the HTML/HEAD element as is - by default.
                If tree or expandables are being used javascript object declarations are
                automatically handled.  If this behavior is not desired then this template
                MUST be overridden.  Likewise if this template is overridden then these
                declarations MUST be included if any tree or exapandable lists are to be
                included."
        >
                <xsl:apply-templates select="HTML_CONTENT/OTHER_SCRIPT/* | HTML_CONTENT/OTHER_SCRIPT/text() | HTML_CONTENT/OTHER_SCRIPT/@*" mode="ibis.copy"/>
                <xsl:if test="exists(HTML_CONTENT/CONTENT[//ibis:ExpandableSection or //ibis:SelectionList])">
                        <script type="text/javascript">
                                var sectionControl = new ShowHideBlockControl("control", "ExpandableSectionControlOpen", "container", "ExpandableSectionContainerShow");
                        </script>
                </xsl:if>
                <xsl:if test="exists(HTML_CONTENT/CONTENT//ibis:SelectionTree)">
                        <script type="text/javascript">
                                var treeControl = new ShowHideBlockControl("control", "Open", "container", null);
                        </script>
                </xsl:if>
        </xsl:template>



        <xsl:template name="Page.sectionsContent" ibis:doc="HTML API template implementation 
                that provides main HTML body content for the page.  Defaults to copying
                all elements and attributes of the the 'HTML_CONTENT/CONTENT' element."
        >
                <!-- used an apply templates so that the ibis: stuff would be handled -->
                <div class="Content">
                        <xsl:apply-templates select="HTML_CONTENT/CONTENT/(text() | *)" mode="ibis.copy"/>
                </div>
        </xsl:template>



        <xsl:template match="HTML_CONTENT/CONTENT//ibis:ExpandableSection" mode="ibis.copy"
                ibis:doc="Provides ability to more easily embed an expandable content block 
                        into the CONTENT.  Note that the approp CSS and JS will need to be 
                        included and initialized.  Code creates a control element with an ID
                        based on the optional NAME sub element.  If NAME doesn't exist then
                        the postion() is used.  This will create unique ID's in most cases.
                        The CONTENT text() and sub elements will be ibis:copied into the assoc
                        content container DIV.
                "
        >
                <xsl:param name="id" select="if(exists(NAME)) then NAME else position()"/>
                <a name="control{$id}" id="control{$id}" 
                        href="javascript:sectionControl.toggle('{$id}');" 
                        class="ExpandableSectionControl {if(exists(SHOW)) then 'ExpandableSectionControlOpen' else ''}" 
                        title="control for {TITLE}"
                ><span class="Icon"/><xsl:value-of select="TITLE"/></a>
                <div id="container{$id}" class="ExpandableSectionContainer {if(exists(SHOW)) then 'ExpandableSectionContainerShow' else ''}">
                        <xsl:apply-templates select="CONTENT/(text() | *)" mode="ibis.copy"/>
                </div><br/>
        </xsl:template>




        <xsl:template match="HTML_CONTENT/CONTENT//ibis:SelectionList" mode="ibis.copy"
                ibis:doc="Provides ability to more easily embed an expandable content list.
                        The initial SELECTIONS/SELECTIONs are the container control with sub
                        SELECTIONS/SELECTIONs being turned into a unordered list.  Note that 
                        the approp CSS and JS will need to be included and initialized.  Code 
                        creates a control element with an ID based on the optional NAME sub 
                        element + position() looping value.  This will create unique ID's in 
                        most cases.
                "
        >
                <xsl:for-each select="SELECTIONS/SELECTION">
                        <xsl:variable name="id" select="concat(NAME, position())"/>
                        <a name="control{$id}" id="control{$id}" 
                                href="javascript:sectionControl.toggle('{$id}');" 
                                class="ExpandableSectionControl {if(exists(SHOW)) then 'ExpandableSectionControlOpen' else ''}" 
                                title="control for {TITLE}"
                        ><span class="Icon"/><xsl:value-of select="TITLE"/></a>
                        <div id="container{$id}" class="ExpandableSectionContainer {if(exists(SHOW)) then 'ExpandableSectionContainerShow' else ''}">
                                <xsl:apply-templates select="current()/SELECTIONS" mode="SelectionList">
                                        <xsl:with-param name="processSubSelections" select="true()"/>
                                </xsl:apply-templates>
                        </div><br/>
                </xsl:for-each>
        </xsl:template>




        <xsl:template match="HTML_CONTENT/CONTENT//ibis:SelectionTree" mode="ibis.copy"
                ibis:doc="Provides ability to more easily create an expandable tree structure
                        based on the standard SELECTIONS/SELECTION structure.  Note that the approp 
                        CSS and JS will need to be included and initialized.  For this to work, 
                        the SELECTIONS element must be a child element.  The parent ID is based
                        on position() thus only enabling one tree per document.
                "
        >
                <xsl:call-template name="SelectionTree.expandableTree">
                        <xsl:with-param name="parentID"        select="position()"/>
                        <xsl:with-param name="title"           select="TITLE"/>
                        <xsl:with-param name="description"     select="DESCRIPTION"/>
                        <xsl:with-param name="selections"      select="SELECTIONS"/>
                        <xsl:with-param name="userAuthorities" select="$UserAuthorities"/>
                </xsl:call-template>
        </xsl:template>



        <xsl:template match="HTML_CONTENT/CONTENT//ibis:SelectionList" mode="ibis.copy"
                ibis:doc="Provides ability to more easily embed a standard list based on 
                        a SELECTIONS/SELECTION structure.  This code handles sub ibis:includes
                        so that a MENU structure can be included.  If the container element 
                        does NOT have a direct child element named SELECTIONS then the optional
                        SELECTIONS_CONTAINER_ELEMENT_NAME can be used.  If the INCLUDE_SUB_LISTS
                        element is present then the list will be processed for sub lists.
                "
        >
                <!-- variable is needed to process any ibis:include statements -->
                <xsl:param name="processedContent">
                        <xsl:apply-templates select="*" mode="ibis.copy"/>
                </xsl:param>
                <xsl:param name="selections"
                        select="
                                if(exists(SELECTIONS_CONTAINER_ELEMENT_NAME)) 
                                        then $processedContent//*[name()=$processedContent/SELECTIONS_CONTAINER_ELEMENT_NAME]/*
                                        else $processedContent
                        "
                />

                <ul>
                        <xsl:apply-templates select="$selections/*" mode="SelectionList">
                                <xsl:with-param name="processSubSelections" select="exists(INCLUDE_SUB_LISTS)"/>
                                <xsl:with-param name="userAuthorities" select="$UserAuthorities"/>
                        </xsl:apply-templates>
                </ul>
        </xsl:template>


        <xsl:template match="HTML_CONTENT/CONTENT//ibis:HELP" mode="ibis.copy"
                ibis:doc="Provides a help balloon button."
        >
                <xsl:call-template name="Page.helpButton">
                        <xsl:with-param name="title" select="TITLE"/>
                        <xsl:with-param name="text"  select="TEXT"/>
                </xsl:call-template>
        </xsl:template>

</xsl:stylesheet>
<!-- ============================= End of File ============================= -->