source: main/adopters/nj/trunk/src/main/webapps/doh-shad/xslt/ibis.xslt @ 18044

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="2.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:xs  ="http://www.w3.org/2001/XMLSchema"
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis xs xsl"
>

        <ibis:doc>
                <name>ibis</name>
                <summary>Library of generic/common ibis specific functions</summary>
                <description>
                        Library of generic/common IBIS specific global variables and functions.
                        These functions are auto included in all pages because this file is 
                        imported by _main.xslt which is a part of all IBISPH-View system HTML 
                        output pages.
                </description>

                <author>Garth Braithwaite</author>
                <company>Software Technology Group/CDC/Ut Department of Health</company>
        </ibis:doc>


        <!-- ========================= P A R A M E T E R S   and   V A R I A B L E S
                The java servlet controller code adds ALL URL query request parameters 
                to the XSLT transformation's parameters.  Other special parameters are
                added as well.  

                Many of the global type parameters are defined within this XSLT file.  
                The parameters are passed in via the Java XSLT transformation parameter 
                map (and thus are nameed according to the Java model map key value).  
                For ease of XSLT code maintenance these global XSLT parameters are 
                wrapped within an "ibis." prefix so that it is shown which XSLT file
                contains the definition.
        -->

        <!-- RESOURCE ADDRESSING: The "WebAppURLContextPrefix" parameter is used to 
                explicitly build URL addresses to site related resources.  The value is 
                typically pulled from the servlet context.  The resource's path is relative
                to the application's root.  The prefix and the relative root address are 
                then concatenated together (along with a separator) to build a complete,
                explicit path for the resource.  This value can either be hard coded as an 
                XSLT variable or in this case is set as a parameter passed in from the 
                XML/XSLT transformer.

                This full context path value is needed because relative paths do not work 
                for sites that have resources under different directory paths.  E.g. the 
                browser tries to get the resource based on the current resource's path.
                Relative paths work well with sites that deliver dynamic content using a 
                servlet call that is located at the root level of the application's context.
                Addressing anything within a site like this using a relative address path 
                works since the current resource's path is the root directory.

                The resource could also be explicitly coded for a given application context 
                (or as the default application - without any context path) but then the code 
                is context deployment dependent and would need changing based on the context 
                the app was deployed under.  So the root "/" can't be used either...

                This solution is messier from an XSLT perspective and in making sure that the 
                XML/XSLT transformer is passed the correct value and inserts the value in as
                the "WebAppURLContextPrefix" parameter.  However, this is a safe way to ensure 
                that the resources are found while remaining deployment context independent.

                OLDER SOLUTIONS:
                If the apps context is the root then this value should be '/'.  If it's
                not then it should be something like: '/ibisph-view/' 
                <xsl:variable name="webappURLContextPrefix" select="'/ibisph-view/'"/>
                <xsl:variable name="webappURLContextPrefix" select="concat('/', SystemServlet:System.getWebAppContextName(), '/')" xmlns:SystemServlet="org.ibisph.servlets.view"/>

                WORKS - should be a little faster than system properties...
                <xsl:variable name="webappURLContextPrefix" select="concat('/', SystemServlet:System.getWebAppContextName(), '/')" xmlns:SystemServlet="org.ibisph.servlet.view"/>

                ALSO WORKS:
                <xsl:variable name="webappURLContext" select="org.ibisph:SystemProperties.getProperty('WebAppContextName')" xmlns:org.ibisph="org.ibisph"/>
                <xsl:variable name="webappURLContextPrefix" select="concat('/', $webappURLContext, '/')"/>

                TRIED: 
                doesn't blow but doesn't have the correct content path either...
                select="concat(java:org.springframework.web.context.support.StaticWebApplicationContext.ROOT_WEB_APPLICATION_CONTEXT_ATTRIBUTE, '/')" xmlns:java="http://xml.apache.org/xslt/java"

                ONE LINE PROPERTY CALL - WORKS:
                <xsl:variable name="webappURLContextPrefix" select="concat('/', org.ibisph:SystemProperties.getProperty('WebAppContextName'), '/')" xmlns:org.ibisph="org.ibisph"/>
                <xsl:variable name="webappURLContextPrefix" select="org.ibisph:SystemProperties.getProperty('WebAppURLContextPrefix')" xmlns:org.ibisph="org.ibisph"/>
        -->
        <xsl:param name="ibis.adopterTitle" select="'State'"
                ibis:doc="Value to be used when the XSLT code needs a title usage example 
                        is CP reports that compare community, state, and US.  This should be
                        overridden in the main ss.xslt with values like 'Utah', 'New Mexico' etc.
                "
        />

        <xsl:param name="WebAppContextURLPrefix" 
                ibis:doc="Prefix used/needed for referencing resources within the site."
        />
        <xsl:variable name="ibis.urlPrefix" select="$WebAppContextURLPrefix"
                ibis:doc="WebAppContextURLPrefix access variable that all pages should use.  
                        Has the 'ibis.' prefix to know what XSLT the variable/param is defined in.
                "
        />

        <xsl:param name="WebAppRemoteURLPrefix" select="$ibis.urlPrefix" 
                ibis:doc="
                        Prefix used/needed for referencing this apps resources outside the 
                        site.  This value is primarily used for the site search.
                "
        />
        <xsl:variable name="ibis.remoteURLPrefix" select="$WebAppRemoteURLPrefix"
                ibis:doc="WebAppRemoteURLPrefix access variable that any pages could use.  
                        Has the 'ibis.' prefix to know what XSLT the variable/param is defined in.
                "
        />

        <xsl:param name="UserProfile"
                ibis:doc="User's XML Profile document.  Must provide a default node type
                        value so that $UserProfile//AUTHORITIES will work when no user profile 
                        doc is injected.  Otherwise the following type of check is needed:
                        xsl:with-param name='userAuthorities' select='if(boolean($UserProfile))then $UserProfile//AUTHORITIES else ''
                "
        />
        <xsl:variable name="ibis.userProfile" 
                ibis:doc="User Profile XML variable that all pages should use.  Has the
                        'ibis.' prefix to know what XSLT the variable/param is defined in.
                "
        >
                <xsl:choose>
                        <xsl:when test="not($UserProfile)">
                                <FULL_NAME>Not Authenticated</FULL_NAME>
                        </xsl:when>
                        <xsl:when test="exists($UserProfile/USER)">
                                <xsl:copy-of select="$UserProfile/USER/*"/>
                        </xsl:when>
                        <xsl:when test="exists($UserProfile)">
                                <xsl:copy-of select="$UserProfile"/>
                        </xsl:when>
                        <xsl:otherwise>
                                <FULL_NAME>Not Authenticated</FULL_NAME>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:variable>
        <xsl:param name="ibis.userAuthorities" select="$ibis.userProfile/AUTHORITIES"
                ibis:doc="Variable used by the ibis:hasAuthority function or can be used directly."
        />


        <xsl:param name="XMLModifedDate"
                ibis:doc="Parameter which is set via the Java model code so that the 
                        resultant page can display the XML file's modified date/time."
        />
        <xsl:variable name="ibis.XMLModifedDate" 
                select="if(string-length($XMLModifedDate) = 0) then //ibis:doc/versions/version[1]/date else $XMLModifedDate"
                ibis:doc="Variable that wraps the 'XMLModifedDate' parameter so that we 
                        know where this variable/parameter is defined.  If the parameter
                        value is not specified then the parameter defaults to selecting the 
                        XML document's ibis:doc version date."
        />


        <!-- tried all sorts of patterns for time zone [ZN,*-3] [ZMST], [ZN,MST] etc... -->
        <xsl:param name="ibis.dateTimeFormatPicture" select="'[FNn,*-3], [D01] [MNn] [Y0001] [H]:[m]:[s]'"/>
        <xsl:param name="ibis.dateFormatPicture"     select="'[FNn,*-3], [D01] [MNn] [Y0001]'"/>
        <xsl:param name="ibis.timeFormatPicture"     select="'[H]:[m]:[s]'"/>


        <!-- ===================================================== G E N E R A L -->
        <xsl:function name="ibis:isFirstLetter_T_or_Y_or_X" as="xs:boolean" 
                ibis:doc="Returns 'true' if the text is 'T'rue, 'Y'es, or 'x' - 'false' otherwise (case insensitive)."
        >
                        <!-- can also be done by regexp -->
                        <xsl:param name="text" ibis:doc="Source text to be tested"/>
                        <xsl:variable name="firstLetter" select="lower-case(substring(normalize-space($text),1,1))"/>
                        <xsl:value-of select="if(($firstLetter='y') or ($firstLetter='t') or ($firstLetter='x')) then true() else false()"/>
        </xsl:function>

        <xsl:function name="ibis:isAuthenticated" as="xs:boolean"
                ibis:doc="localizes checking the UserProfile param exists as a node.  
                        Note the not not is needed to handle string vs node xslt problem.  
                        Exists returns true for any/all defined variables/params.  not 
                        handles a null or zero len string as false and also handles an 
                        empty node set as false.
                "
        >
                <xsl:value-of select="not(not($UserProfile))"/>
        </xsl:function>

        <xsl:function name="ibis:hasAuthorities" as="xs:boolean"
                ibis:doc="localizes checking if the user is authenticated and if so if
                        they have an authority (secure type user).
                "
        >
                <xsl:value-of select="if(ibis:isAuthenticated()) then exists($ibis.userAuthorities/AUTHORITY) else false()"/>
        </xsl:function>

        <xsl:function name="ibis:hasAuthority" as="xs:boolean"
                ibis:doc="localizes checking the user authorities against the passed in 
                        AUTHORITY.  If an AUTHORITY's text() matches one of the user's 
                        AUTHORITY values then true is returned.  Else false is returned.  
                        This function is dependent on the global UserAuthorities param 
                        which needs to be injected via the java controller/transformer code.
                "
        >
                <xsl:param name="authority" ibis:doc="AUTHORITY value to be tested for."/>
                <xsl:value-of select="not(exists($authority)) or exists($ibis.userAuthorities[AUTHORITY = $authority])"/>
        </xsl:function>



        <!-- =========================== F O R M A T T I N G   F U N C T I O N S -->
        <xsl:decimal-format name="ibis.defaultDecimalNumberFormat" NaN=" * " zero-digit="0"
                ibis:doc="Default format for the 'ibis:formatNumber function."
        />
        <xsl:param name="ibis.defaultNumericPicture" select="',##0.##'"
                ibis:doc="default number picture format.  Done as a variable so that 
                site specefic templates can override."
        />

        <!-- XSLT 2.0 does NOT provide for any literals inside the picture string that are 
        defined as a format character.  So to embed a "%" sign without actually multiplying
        the value by 100 a format picture in XSLT 1.0 could simply be "#.#'%'".  In XSLT 2
        it shows the #.#'%' with the value multiplied.  The way to get around this is to
        change the % character with the decimal numeric format.  However some value will
        need to be multiplied so the easiest way to deal with this is to simply replace
        '%' with '' and add the % character to the end of the string.
        See: http://www.w3.org/TR/xslt20/#defining-decimal-format.

        Below is an example of how to redefine the % character:
        <xsl:decimal-format name="ibis.percentSuffixDecimalNumberFormat" NaN=" * " zero-digit="0" percent="^"
                ibis:doc="Decimal format that redefines the % character so it doesn't interfere with the 
                        format picture string."
        />
        -->
        <xsl:param name="ibis.numberFormatQuotedPercentString" ibis:doc="Percentage 
                suffix signature to be searched and replaced with null and which signals 
                to concat the % sign to the end of the formatted value.  This value should
                match the value used by the admin system to signify that a % should be 
                added as a numeric suffix.  If the % is standalone then the value should 
                be of the form 0.xx which will then cause the format number code to mult 
                by 100 and add the %.  Otherwise the value will be displayed 100x's too
                large (xx00.00%)."
        >'%'</xsl:param>



        <xsl:function name="ibis:getJavaScriptValue" as="xs:string"
                ibis:doc="If value exists then returns value otherwise null."
        >
                <xsl:param name="value" ibis:doc="Value to be tested."/>
<!--
                <xsl:value-of select="if(starts-with($value, '*') or (string-length($value) = 0))then 'null' else $value"/>
-->
                <xsl:value-of select="if((string(number($value)) = 'NaN') or (string-length($value) = 0))then 'null' else $value"/>
        </xsl:function>



        <xsl:function name="ibis:getFormattedNumber" as="xs:string"
                ibis:doc="Numeric formatter that localizes the handling of numeric values.
                If a format is not specified then the common.defaultFormat is used."
        >
                <xsl:param name="number" ibis:doc="Value to be formatted.  If the value is
                        non numeric then that value will be returned.  Otherwise the format
                        picture will be applied."
                />
                <xsl:param name="picture" ibis:doc="Format to be applied.  If '' is specified
                        then the ibis.defaultNumericPicture is used.  If 'none' is specified then
                        the actual value passed in will be used."
                />
                <xsl:value-of select="ibis:getFormattedValue($number, $picture, '')"/>
        </xsl:function>


        <xsl:function name="ibis:getFormattedValue" as="xs:string"
                ibis:doc="Numeric formatter that localizes the handling of numeric values
                        with a default null value.  If a format is not specified then the 
                        common.defaultFormat is used.
                "
        >
                <xsl:param name="number" ibis:doc="Value to be formatted.  If the value is
                        non numeric then that value will be returned.  Otherwise the format
                        picture will be applied."
                />
                <xsl:param name="picture" ibis:doc="Format to be applied.  If '' is specified
                        then the ibis.defaultNumericPicture is used.  If 'none' is specified then
                        the actual value passed in will be used."
                />
                <xsl:param name="valueIfNull" 
                        ibis:doc="Value to use if the number param value is not something."
                />

<!--
<xsl:message select="'using the picture'"/>
<xsl:message select="'when percent'"/>
<xsl:message select="'otherwise using default picture'"/>
<xsl:message select="concat('ibis:getFormattedValue - number: ', $number, ', value: ', $value, ', Picture: ', $picture, ', valueIfNull: ', $valueIfNull)"/>
-->
                <xsl:variable name="value">
                        <xsl:choose>
                                <xsl:when test="count($number) &gt; 1">
<xsl:message select="'ibis:getFormattedValue - number is a sequence of the following values: '"/>
<xsl:message select="$number"/>
                                        -999999
                                </xsl:when>
                                <xsl:when test="(string-length(string($number)) != 0) or not($valueIfNull)">
                                        <xsl:value-of select="$number"/>
                                </xsl:when>
                                <xsl:otherwise>
                                        <xsl:value-of select="$valueIfNull"/>
                                </xsl:otherwise>
                        </xsl:choose>
                </xsl:variable>
                <xsl:choose>
                        <xsl:when test="$picture='none'"><xsl:value-of select="$value"/></xsl:when>

                        <xsl:when test="string(number($value))='NaN'"><xsl:value-of select="$value"/></xsl:when>

                        <!-- put this in because UT had some messed up QM configurations -->
                        <xsl:when test="count($picture) &gt; 1">
                                <xsl:message select="'***ibis:getFormattedValue - TOO MANY XSLT FORMATS***, picture:'"/>  
                                <xsl:message select="$picture"/>
                                <xsl:value-of select="'CONTENT ERROR - TOO MANY XSLT FORMATS - PLEASE CONTACT US!!!'"/>
                        </xsl:when>

                        <!-- if format string was passed in, then check for the '%' string.
                                If found then need to replace with a null and add the % to the 
                                end.  See comments about about how XSLT 2.0 does not allow for
                                literals that match one of the defined format control chars 
                                without effecting formatting. 

                                Else if the string doesn't contain the special percent character 
                                suffix signature then simply use as is.
                        -->
                        <xsl:when test="string-length($picture) != 0">
                                <xsl:choose>
                                        <xsl:when test="contains($picture, $ibis.numberFormatQuotedPercentString)">
                                                <xsl:value-of select="concat(format-number($value, replace($picture,$ibis.numberFormatQuotedPercentString,''), 'ibis.defaultDecimalNumberFormat'), '%')"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                                <xsl:value-of select="format-number($value, $picture, 'ibis.defaultDecimalNumberFormat')"/>
                                        </xsl:otherwise>
                                </xsl:choose>
                        </xsl:when>

                        <xsl:otherwise>
                                <xsl:value-of select="format-number($value, $ibis.defaultNumericPicture, 'ibis.defaultDecimalNumberFormat')"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:function>


        <!-- See: http://stackoverflow.com/questions/16892344/convert-a-string-to-date-format-in-xslt -->
        <xsl:function name="ibis:getFormattedDateTime" as="xs:string" 
                ibis:doc="Localizes date and time formatting.  Uses the ibis.dateTimeFormatPicture param."
        >
                <xsl:param name="dateTime" ibis:doc="DateTime value to be formatted.  
                        Call with current-dateTime() to get current system date and time."
                />
                <xsl:value-of select="format-dateTime($dateTime, $ibis.dateTimeFormatPicture)"/>
        </xsl:function>
        <xsl:function name="ibis:getFormattedDate" as="xs:string" 
                ibis:doc="Localizes date formatting.  Uses the ibis.dateFormatPicture param."
        >
                <xsl:param name="date" ibis:doc="Date value to be formatted.  Call with 
                        current-date() to get current system date."
                />
                <xsl:value-of select="format-date($date, $ibis.dateFormatPicture)"/>
        </xsl:function>
        <xsl:function name="ibis:getFormattedTime" as="xs:string" 
                ibis:doc="Localizes time formatting.  Uses the ibis.timeFormatPicture param."
        >
                <xsl:param name="time" ibis:doc="Time value to be formatted.  Call with 
                        current-time() to get current system time."
                />
                <xsl:value-of select="format-time($time, $ibis.timeFormatPicture)"/>
        </xsl:function>


        <xsl:function name="ibis:getCompleteIndicatorViewTitle" as="xs:string"
                ibis:doc="Builds a complete view title."
        >
                <xsl:param name="indicatorView" ibis:doc="Indicator Profile View to be used to build the title from."/>
                <xsl:value-of select="concat($indicatorView/TITLE, ' ', $indicatorView/SUB_TITLE, ' ', $indicatorView/PERIOD_TITLE)"/> 
        </xsl:function>
        <xsl:function name="ibis:getPartialIndicatorViewTitle" as="xs:string"
                ibis:doc="Builds the view's partial, most specific title."
        >
                <xsl:param name="indicatorView" ibis:doc="Indicator Profile View to be used to build the title from."/>
                <xsl:value-of select="concat($indicatorView/SUB_TITLE, ' ', $indicatorView/PERIOD_TITLE)"/> 
        </xsl:function>



        <!-- ===================================== M A T C H   C O P Y   M O D E -->
        <xsl:template match="*" mode="ibis.copy"
                ibis:doc="Provides the ability to do an apply-templates to a copy-of of
                        an element (some call this an 'identity transformation').  This 
                        allows for a deep copy with processing (which also allows ibis.include 
                        to be processed)."
        >
                <!-- Used the new element and copied the attributes, text, and sub 
                        elements so that any namespace attributes would not be copied.
                        <xsl:apply-templates select="@*" mode="ibis.copy"/>
<xsl:message>IBIS.COPY</xsl:message>
                -->
                <xsl:element name="{local-name()}">
                        <xsl:apply-templates select="current()/@* | current()/text() | current()/*"  mode="ibis.copy"/>
                </xsl:element>
        </xsl:template>


        <xsl:template match="text()" mode="ibis.copy" ibis:doc="copies the text.">
<!-- trims the text - not really needed for wiki - biggest issue with weird text
        was page indent on and extra line spacing etc.
                <xsl:value-of select="replace(., '^\s+|\s+$', '')"/>
-->
                <xsl:value-of select="."/>
        </xsl:template>

        <!-- Match Copy Mode was lifted from the page.xslt in 4/2007.  That code has a note
                about 4-18-06: removed template code and replaced with the mode="ibis.copy"
                templates above because the namespace was being copied into some HTML elements.
                See: http://www.stylusstudio.com/xsllist/200008/post50850.html
        -->

        <!-- The following templates are used to help page developers avoid having to 
                hard code the deployment specific context into the URL path of IBIS related
                web pages.  Example: If the app is deployed into a context called "ibisph-view"
                and your page is "http://localhost/ibisph-view/about/welcome.html" and it 
                references an image that is under the "webapps/ibisph-view/image" directory
                it would need a url like "src='/ibisph-view/image/the_image.gif'" to properly
                get the correct resource.  A relative path of "src='image/the_image.gif'" 
                would cause the browser to request "http://localhost/ibisph-view/about/image/the_image.gif",
                while a path of "src='/image/the_image.gif'" would request this resource
                "http://localhost/image/the_image.gif" both of which are wrong.  If the context
                path is coded so that the resource's URL is explicitly defined then a dependency
                exists between the web pages and the context which makes the deployment not
                as portable.  Since the web app context path is needed by the XSLTs to build
                the correct HTML code it is implemented here to help static page development.
                Relative links work fine if the resource it within the same directory e.g. 
                if the "about/welcome.html" page contains a relative link to the "about/content_usage.html" 
                page then all is well.  The "about/welcome.html" page can NOT contains a relative 
                link to the "indicator/introduction.html" as it will not find the correct
                directory.
        -->

        <!-- Local IBIS URL adjustment templates.  These templates simply add the web application's
                context path as a prefix to the link reference attribute.
        -->
        <xsl:template match="@ibis:href" mode="ibis.copy" ibis:doc="Inner 'ibis:href' template that adds the 'WebAppURLContextPrefix' to the 'href' attribute.">
                <xsl:attribute name="href" select="concat($ibis.urlPrefix, .)"/>
        </xsl:template>
        <xsl:template match="@ibis:src" mode="ibis.copy" ibis:doc="Inner 'ibis:src' template that adds the 'WebAppURLContextPrefix' to the 'src' attribute.">
                <xsl:attribute name="src" select="concat($ibis.urlPrefix, .)"/>
        </xsl:template>
        <xsl:template match="@ibis:action" mode="ibis.copy" ibis:doc="Inner 'ibis:action' template that adds the 'WebAppURLContextPrefix' to the 'action' attribute.">
                <xsl:attribute name="action" select="concat($ibis.urlPrefix, .)"/>
        </xsl:template>

        <xsl:template match="ibis:urlPrefix" mode="ibis.copy" ibis:doc="Mechanism that allows the HTML_CONTENTN PAGE type XML content to get the ibis:urlPrefix value.  This is useful for pages that have javascript that need this value.">
                <xsl:value-of select="$ibis.urlPrefix"/>
        </xsl:template>

        <xsl:template match="@*" mode="ibis.copy" ibis:doc="Inner '@*' template that copies the non ibis: namespace attributes">
                <xsl:copy-of select="."/>
        </xsl:template>

        <xsl:template match="@ibis:doc" mode="ibis.copy" ibis:doc="Eats ibis:doc attribute"/>
        <xsl:template match="ibis:doc"  mode="ibis.copy" ibis:doc="Eats ibis:doc element"/>



        <!-- =============================== I B I S   I N C L U D E   M A T C H -->
        <xsl:template match="ibis:include" mode="#all"
                ibis:doc="
                        'ibis:' namespace specific match template which opens 
                        the document via the 'href' attribute and does an 'apply-template'
                        operation on its contents to process sub 'ibis:include' statements
                        and to copy its text, attributes, and processing instructions.

                        Provides the IBISPH system the ability to do simple xinclude 
                        type operations.  As of 6-2004 the xerces parser 2.6.x has xinclude support 
                        but it must be configured when starting the Java JVM or with Java system
                        properties.  Since this might not be an option for some deployments (like 
                        Utah's state wide ITS app server) the system wide property solution is not
                        an option.  To handle being able to deploy into environments where we don't 
                        know which XSL engine is being used this two step xinclude processing 
                        was developed.  This option is not nearly as seamless and requires that 
                        the java controller do 2 transformations - the first being this xinclude
                        type transformation with the second being the normal desired page type
                        transformation.  Another option was to do the xinclude template inside the 
                        XSLT as a variable then use that variable for all XML nodes.  This option 
                        appears to be somewhat slow but it is seamless.

                        See: http://www.sagehill.net/docbookxsl/Xinclude.html

                        This page simply copies the contents of the base document and when it 
                        hits the ibis:include element it opens the document with an XSLT document 
                        call based on the href attribute of the xi:include element.  These 
                        elements are then copied into the source document.

                        NOTE: the included document MUST be a valid XML file e.g. well 
                        formed with a root/master/parent element.

                        If an children-only-flag attribute exists in the element then only
                        only the sub elements and child text are included and processed.
                        This is useful for including an element's text without having to 
                        include its root element.
                "
        >
<!-- this only copies child content - skips container element.
                <xsl:copy>
                        <xsl:apply-templates select="document(@href, /)" mode="ibis.include"/>
                </xsl:copy>
<xsl:message select="document(@href, /)"/>
<xsl:message select="concat('FOUND IBIS INCLUDE: ', @href)"/>

                <xsl:choose>
                        <xsl:when test="exists(@include-children-only)">
                                <xsl:apply-templates select="document(@href, /)/(text() | *)" mode="ibis.copy"/>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:apply-templates select="document(@href, /)" mode="ibis.copy"/>
                        </xsl:otherwise>
                </xsl:choose>
 -->
<!--xsl:message select="'=================================================='"/>
<xsl:message select="document(@href, /)"/>
<xsl:message select="concat('FOUND IBIS INCLUDE: ', @href)"/-->
                <xsl:apply-templates select=
                        "if(exists(@children-only-flag)) 
                                then document(@href, /)/(text() | *)
                                else document(@href, /)
                        "
                        mode="ibis.copy"
                />
        </xsl:template>

</xsl:stylesheet>



<!-- left here for posterity - a way to totally replace an element...
        <xsl:template match="ibis:a">
                <xsl:element name="a">
                        <xsl:attribute name="href"><xsl:value-of select="concat($ibis.urlPrefix, @href)"/></xsl:attribute>
                        <xsl:copy-of select="attribute::*[name() != 'href']"/>
                        <xsl:apply-templates select="current()/text() | current()/*"/>
                </xsl:element>
        </xsl:template>
-->
<!-- img elements do not contain any text or other elements so it doesn't need
                to process/worry about anything other than it's attributes.
        <xsl:template match="ibis:img">
                <img>
                        <xsl:attribute name="src"><xsl:value-of select="concat($ibis.urlPrefix, @src)"/></xsl:attribute>
                        <xsl:copy-of select="attribute::*[name() != 'src']"/>
                </img>
        </xsl:template>
-->
<!-- Since the a element can contain images, divs etc need to process text
                and elements contained within.
        <xsl:template match="ibis:form">
                <xsl:element name="form">
                        <xsl:attribute name="action"><xsl:value-of select="concat($ibis.urlPrefix, @action)"/></xsl:attribute>
                        <xsl:copy-of select="attribute::*[name() != 'action']"/>
                        <xsl:apply-templates select="current()/text() | current()/*"/>
                </xsl:element>
        </xsl:template>
-->

<!-- ============================= End of File ============================= -->