source: main/adopters/nd/trunk/src/main/webapps/ibisph-view/xslt/html/indicator/index/alphabetical/Page.xslt @ 19698

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="2.0" 
        xmlns:xsl ="http://www.w3.org/1999/XSL/Transform" 
        xmlns:ibis="http://www.ibisph.org"

        exclude-result-prefixes="ibis"
>
        <xsl:import href="../../../Page.xslt"/>


        <xsl:param name="Page.pageTitle" ibis:doc="Page's title text.">Alphabetical Health Report Selection List</xsl:param>

        <xsl:param name="alphabet" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
        <xsl:variable name="alphabetLength" select="string-length($alphabet)"/>


        <xsl:template name="Page.sectionsContent"
                ibis:doc="Main page content template that creates an HTML table
                        which lists all the indicator's with a link to their default
                        indicator profile view."
        >
                Welcome to the alphabetical selection list of all available health indicator 
                reports. To view a health indicator profile report, click on the item's title 
                located in the following list.  
                <br/><br/>

                <xsl:call-template name="alphaJumpToLine"/>
                <table cellspacing="0" cellpadding="0" border="1" class="Info ExtraCellPadding"
                        summary="Alphabetical listing for all indicator profile selections.
                                First column contains the indicator profile link with the title
                                being the indicator profile title.  The next column provides the
                                published date for that indicator profile.
                        "
                        caption="Alphabetical listing for all indicator profile selections."
                >
                        <thead><tr>
                                <th scope="col" width="450" title="To view the default chart and basic indicator information, click on the indicator's title below.">Indicator Profile Title</th>
                                <th scope="col" width="100" title="This is the date these data were certified current and valid.">Published Date</th>
                        </tr></thead>
                        <tfoot><tr><td colspan="2">
                                <div class="RecordCount">Record Count: <xsl:value-of select="count(/INDICATORS/INDICATOR)"/></div>
                        </td></tr></tfoot>

                        <!-- loop for all published indicators -->
                        <tbody>
                                <xsl:for-each select="/INDICATORS/INDICATOR">
                                <xsl:sort select="TITLE"/>
                                        <tr>
                                                <td><a name="{substring(TITLE, 1, 1)}" 
                                                                href="{concat($ibis.urlPrefix, 'indicator/view/', DEFAULT_INDICATOR_VIEW_NAME, '.html')}"
                                                                title="Click here to see the default chart for {TITLE}">
                                                        <xsl:value-of select="TITLE"/>
                                                </a></td>
                                                <td class="TextAlignCenter" title="Data as of Date: {DATA_SOURCE_DATE}">
                                                        <xsl:value-of select="PUBLISHED_DATE"/>
                                                </td>
                                        </tr>
                                </xsl:for-each>
                        </tbody>
                </table>
                <br/>
                <xsl:call-template name="alphaJumpToLine"/>
        </xsl:template>



        <xsl:template name="alphaJumpToLine" ibis:doc="Internal helper that displays the alpha jump to links.">
                <div class="JumpToLinks">
                        Index:
                        <xsl:call-template name="alphaAnchorJumpTo">
                                <xsl:with-param name="position" select="1"/>
                        </xsl:call-template>
                </div>
        </xsl:template>



        <xsl:template name="alphaAnchorJumpTo" ibis:doc="Internal helper used by the 'alphaJumpToLine' template  to build the 'a' link character.">
                <xsl:param name="position"/>

                <xsl:param name="letter" select="substring($alphabet, $position, 1)"/>
                <a href="#{$letter}" title="Jump to the indicators that begin with {$letter}"><xsl:value-of select="$letter"/></a> 

                <xsl:if test="$position &lt; $alphabetLength">
                        <xsl:call-template name="alphaAnchorJumpTo">
                                <xsl:with-param name="position" select="number($position) + 1"/>
                        </xsl:call-template>
                </xsl:if>
        </xsl:template>

</xsl:stylesheet>
<!-- ============================= End of File ============================= -->